.TITLE	PARSE822_TABLES - TPARSE tables for PARSE822
	.IDENT	'V1.3'

;
;       Determine target platform (avoids having to use
;       ARCH_DEFS.MAR)
;

        .NTYPE  R22TYPE,R22             ; get symbol type for "R22"
R22TYPE =       <R22TYPE@-4&^XF>-5      ; type 5 = register
        .IF     EQ,R22TYPE
EVAX    =       1
BIGPAGE =       1
ADDRESSBITS =   32
        .ENDC

	.EXTRN	PARSE822_STORE
	.DSABL	GLOBAL

P8_K_STORE_MBOX	= 231422
P8_K_STORE_FILE = 104987
P8_K_APPND_MBOX	= 861324
P8_K_APPND_REMO = 743892
P8_K_APPND_DNET = 518346
P8_K_STORE_NAME	= 318417
P8_K_STORE_INDI	= 694053

;
; MACRO can't handle some characters as literals.
;
LEFTANGLE	= 60
RIGHTANGLE	= 62
APOSTROPHE	= 39
COMMA		= 44
LEFTBRACE	= 123
VERTBAR		= 124
RIGHTBRACE	= 125
TILDE		= 126

	$INIT_STATE PARSE822_STATE, PARSE822_KEY

	$STATE	SKIPWS
	$TRAN	TPA$_BLANK, SKIPWS
	$TRAN	TPA$_LAMBDA, GETADR1

	$STATE	GETADR1
	$TRAN	!COMMENT, SKIPWS, P8_STORE,,,P8_K_STORE_NAME
	$TRAN	!MAILBOX, CHKCOM
	$TRAN	!PHRASE, SKIPWS, P8_STORE,,,P8_K_STORE_NAME

	$STATE	MAILBOX
	$TRAN	!FILEREF, TPA$_EXIT
	$TRAN	!INDIRECT, TPA$_EXIT
	$TRAN	!ROUTEADR, TPA$_EXIT
	$TRAN	!ADDRSPEC, TPA$_EXIT
	$TRAN	!DNETADR, TPA$_EXIT
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	CHKCOM
	$TRAN	TPA$_BLANK, CHKCOM
	$TRAN	TPA$_EOS, TPA$_EXIT
	$TRAN	!COMMENT, CHKCOM, P8_STORE,,,P8_K_STORE_NAME

	$STATE	COMMENT
	$TRAN	'(', COM1

	$STATE	COM1
	$TRAN	!COMMENT, COM1
	$TRAN	TPA$_BLANK, COM1
	$TRAN	'\', COMLIT
	$TRAN	')', TPA$_EXIT
	$TRAN	TPA$_EOS, TPA$_FAIL
	$TRAN	TPA$_ANY, COM1

	$STATE	COMLIT
	$TRAN	TPA$_ANY, COM1

	$STATE	DNETADR
	$TRAN	':', TPA$_FAIL
	$TRAN	TPA$_BLANK,DNETADR
	$TRAN	TPA$_ANY,DNET1,P8_STORE,,,P8_K_STORE_MBOX

	$STATE	DNET1
	$TRAN	':',DNET2,P8_STORE,,,P8_K_APPND_DNET
	$TRAN	TPA$_BLANK,TPA$_FAIL
	$TRAN	TPA$_ANY,DNET1,P8_STORE,,,P8_K_APPND_MBOX

	$STATE	DNET2
	$TRAN	':',DNET3,P8_STORE,,,P8_K_APPND_MBOX

	$STATE	DNET3
	$TRAN	TPA$_EOS, TPA$_EXIT
	$TRAN	TPA$_BLANK, TPA$_EXIT
	$TRAN	'"',DNETQ,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	'_',DNET3,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	'$',DNET3,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	TPA$_ALPHA,DNET3,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	TPA$_DIGIT,DNET3,P8_STORE,,,P8_K_APPND_MBOX

	$STATE	DNETQ
	$TRAN	'"',DNETQQ,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	TPA$_ANY,DNETQ,P8_STORE,,,P8_K_APPND_MBOX

	$STATE	DNETQQ
	$TRAN	'"',DNETQ,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	TPA$_LAMBDA,DNET3

	$STATE	FILEREF
	$TRAN	TPA$_BLANK,FILEREF
	$TRAN	'*',FILEREF1,P8_STORE,,,P8_K_STORE_FILE

	$STATE	INDIRECT
	$TRAN	TPA$_BLANK,INDIRECT
	$TRAN	'@',FILEREF1,P8_STORE,,,P8_K_STORE_INDI

	$STATE	FILEREF1
	$TRAN	TPA$_BLANK,TPA$_EXIT
	$TRAN	TPA$_EOS,TPA$_EXIT
	$TRAN	'"',FILEREFQ,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	TPA$_ANY,FILEREF1,P8_STORE,,,P8_K_APPND_MBOX

	$STATE	FILEREFQ
	$TRAN	'"',FILEREFQQ,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	TPA$_ANY,FILEREFQ,P8_STORE,,,P8_K_APPND_MBOX

	$STATE	FILEREFQQ
	$TRAN	'"',FILEREFQ,P8_STORE,,,P8_K_APPND_MBOX
	$TRAN	TPA$_LAMBDA,FILEREF1

	$STATE	ROUTEADR
	$TRAN	LEFTANGLE, RTADR1, P8_STORE,,,P8_K_STORE_MBOX
	$TRAN	TPA$_BLANK, ROUTEADR
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	RTADR1
	$TRAN	'@', RTADR2, P8_STORE,,, P8_K_APPND_REMO
	$TRAN	!ADDRSPEC, RTADR5
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	RTADR2
	$TRAN	!DOMAIN, RTADR3, P8_STORE,,, P8_K_APPND_MBOX
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	RTADR3
	$TRAN	COMMA, RTADR1, P8_STORE,,, P8_K_APPND_MBOX
	$TRAN	':', RTADR4, P8_STORE,,, P8_K_APPND_MBOX
	$TRAN	TPA$_BLANK, RTADR3
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	RTADR4
	$TRAN	!ADDRSPEC, RTADR5
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	RTADR5
	$TRAN	TPA$_BLANK, RTADR5
	$TRAN	RIGHTANGLE, TPA$_EXIT, P8_STORE,,, P8_K_APPND_MBOX

	$STATE	ADDRSPEC
	$TRAN	TPA$_BLANK, ADDRSPEC
	$TRAN	!COMMENT, ADDRSPEC, P8_STORE,,, P8_K_STORE_NAME
	$TRAN	!LCLPART, ADRS1, P8_STORE,,, P8_K_APPND_MBOX
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	ADRS1
	$TRAN	'@', ADRS2, P8_STORE,,, P8_K_APPND_REMO
	$TRAN	TPA$_BLANK, ADRS1
	$TRAN	!COMMENT, ADRS1, P8_STORE,,, P8_K_STORE_NAME
	$TRAN	TPA$_EOS, TPA$_EXIT
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	ADRS2
	$TRAN	TPA$_BLANK, ADRS2
	$TRAN	!COMMENT, ADRS2
	$TRAN	!DOMAIN, ADRS3, P8_STORE,,, P8_K_APPND_MBOX
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	ADRS3
	$TRAN	TPA$_BLANK, ADRS3
	$TRAN	!COMMENT, ADRS3
	$TRAN	TPA$_LAMBDA, TPA$_EXIT

	$STATE	LCLPART
	$TRAN	!_WORD, LCLP1
	$TRAN	TPA$_LAMBDA, TPA$_FAIL
	$STATE	LCLP1
	$TRAN	'.', LCLP2
	$TRAN	TPA$_LAMBDA, TPA$_EXIT
	$STATE	LCLP2
	$TRAN	!_WORD, LCLP1
	$TRAN	TPA$_LAMBDA, TPA$_EXIT

	$STATE	PHRASE
	$TRAN	!_WORD, PHR1
	$TRAN	!COMMENT, PHR1
	$TRAN	TPA$_LAMBDA, TPA$_FAIL
	$STATE	PHR1
	$TRAN	TPA$_BLANK, PHR2
	$TRAN	TPA$_LAMBDA, TPA$_EXIT
	$STATE	PHR2
	$TRAN	TPA$_BLANK, PHR2
	$TRAN	!_WORD, PHR1
	$TRAN	!COMMENT, PHR1
	$TRAN	TPA$_LAMBDA, TPA$_EXIT

	$STATE	_WORD
	$TRAN	'"', WORDQ
	$TRAN	!COMMENT, _WORD
	$TRAN	TPA$_ALPHA, WORD1
	$TRAN	TPA$_DIGIT, WORD1
	$TRAN	'`', WORD1
	$TRAN	TILDE, WORD1
	$TRAN	'!', WORD1
	$TRAN	'#', WORD1,
	$TRAN	'$', WORD1
	$TRAN	'%', WORD1
	$TRAN	'^', WORD1
	$TRAN	'&', WORD1
	$TRAN	'*', WORD1
	$TRAN	'-', WORD1
	$TRAN	'_', WORD1
	$TRAN	'=', WORD1
	$TRAN	'+', WORD1
	$TRAN	LEFTBRACE, WORD1
	$TRAN	RIGHTBRACE, WORD1
	$TRAN	APOSTROPHE, WORD1
	$TRAN	VERTBAR, WORD1
	$TRAN	'/', WORD1
	$TRAN	'?', WORD1
	$TRAN	TPA$_LAMBDA, TPA$_FAIL

	$STATE	WORDQ
	$TRAN	'\', WORDQ1
	$TRAN	'"', WORD1
	$TRAN	TPA$_ANY, WORDQ

	$STATE	WORDQ1
	$TRAN	TPA$_ANY, WORDQ

	$STATE	WORD1
	$TRAN	'"', WORDQ
	$TRAN	!COMMENT, WORD1
	$TRAN	TPA$_ALPHA, WORD1
	$TRAN	TPA$_DIGIT, WORD1
	$TRAN	'`', WORD1
	$TRAN	TILDE, WORD1
	$TRAN	'!', WORD1
	$TRAN	'#', WORD1
	$TRAN	'$', WORD1
	$TRAN	'%', WORD1
	$TRAN	'^', WORD1
	$TRAN	'&', WORD1
	$TRAN	'*', WORD1
	$TRAN	'-', WORD1
	$TRAN	'_', WORD1
	$TRAN	'=', WORD1
	$TRAN	'+', WORD1
	$TRAN	LEFTBRACE, WORD1
	$TRAN	RIGHTBRACE, WORD1
	$TRAN	APOSTROPHE, WORD1
	$TRAN	VERTBAR, WORD1
	$TRAN	'/', WORD1
	$TRAN	'?', WORD1
	$TRAN	TPA$_LAMBDA, TPA$_EXIT

	$STATE	DOMAIN
	$TRAN	!SUBDOMAIN, DOM1
	$TRAN	TPA$_LAMBDA, TPA$_FAIL
	$STATE	DOM1
	$TRAN	'.', DOM2
	$TRAN	TPA$_LAMBDA, TPA$_EXIT
	$STATE	DOM2
	$TRAN	!SUBDOMAIN, DOM1
	$TRAN	TPA$_LAMBDA, TPA$_EXIT

	$STATE	SUBDOMAIN
	$TRAN	'[', SUBDLIT
	$TRAN	'`', SUBD1
	$TRAN	TILDE, SUBD1
	$TRAN	'!', SUBD1
	$TRAN	'#', SUBD1
	$TRAN	'$', SUBD1
	$TRAN	'%', SUBD1
	$TRAN	'^', SUBD1
	$TRAN	'&', SUBD1
	$TRAN	'*', SUBD1
	$TRAN	'-', SUBD1
	$TRAN	'_', SUBD1
	$TRAN	'=', SUBD1
	$TRAN	'+', SUBD1
	$TRAN	LEFTBRACE, SUBD1
	$TRAN	RIGHTBRACE, SUBD1
	$TRAN	APOSTROPHE, SUBD1
	$TRAN	VERTBAR, SUBD1
	$TRAN	'/', SUBD1
	$TRAN	'?', SUBD1
	$TRAN	TPA$_ALPHA, SUBD1
	$TRAN	TPA$_DIGIT, SUBD1
	$TRAN	TPA$_LAMBDA, TPA$_FAIL
	$STATE	SUBDLIT
	$TRAN	'\', SUBDLQ
	$TRAN	']', TPA$_EXIT
	$TRAN	TPA$_ANY, SUBDLIT
	$STATE	SUBDLQ
	$TRAN	TPA$_ANY, SUBDLIT
	$STATE	SUBD1
	$TRAN	'`', SUBD1
	$TRAN	TILDE, SUBD1
	$TRAN	'!', SUBD1
	$TRAN	'#', SUBD1
	$TRAN	'$', SUBD1
	$TRAN	'%', SUBD1
	$TRAN	'^', SUBD1
	$TRAN	'&', SUBD1
	$TRAN	'*', SUBD1
	$TRAN	'-', SUBD1
	$TRAN	'_', SUBD1
	$TRAN	'=', SUBD1
	$TRAN	'+', SUBD1
	$TRAN	LEFTBRACE, SUBD1
	$TRAN	RIGHTBRACE, SUBD1
	$TRAN	APOSTROPHE, SUBD1
	$TRAN	VERTBAR, SUBD1
	$TRAN	'/', SUBD1
	$TRAN	'?', SUBD1
	$TRAN	TPA$_ALPHA, SUBD1
	$TRAN	TPA$_DIGIT, SUBD1
	$TRAN	TPA$_LAMBDA, TPA$_EXIT

	$END_STATE

	.PSECT	P8_CODE,NOWRT,SHR,PIC,EXE
P8_STORE:
	.IF	DF,EVAX
	.CALL_ENTRY HOME_ARGS=TRUE,MAX_ARGS=1
	.IFF
	.WORD	0
	.ENDC
	CALLG	(AP),G^PARSE822_STORE
	RET

	.END